LOGO-L> Re: Recursive Stars

["Olga Tuzova" <olgatu@hotmail.com>]

Yehuda Katz wrote:

>Hello Turtlers,
>
>Recently George enabled single-index colors. This makes things easier
>in MSWLogo than before to teach/study Recursive Graphics, by assigning
>to each "level" its corresponding color index (Blue=1, etc.).
>
>The following program, I think, should run on every flavor of Logo:
>

[...]

Dear Yehuda,

Of course, I couldn't pass by your "Krasnaya Zvezda". The essential part 
of my life has gone under it's misleading shine. :-)
But as you haven't left any place for new ideas in your marvelous 
program, I just presume to offer you some "control coat" for it. Please 
try to run star.main in MSW Logo.

Shabat Shalom,
Olga.

---------------------
to do :sides :head_ang :size  :level
if :level<1[stop]
rt 180
repeat :sides[rt turn shape rt turn]
fill_it
rt 180
end

to fill_it
pu bk 2 setfc :level fill fd 2 pd
end

to main
cs ht
do scrollbarget "sides scrollbarget "head_angle ~
   scrollbarget "size scrollbarget "level
end

to shape
fd :size lt :head_ang/2
do :sides :head_ang .4*:size :level-1
lt :head_ang/2 bk :size
end

to star.control.setup

buttoncreate "panel "stop [Exit] 55 125 35 15 [windowdelete "panel]
buttoncreate "panel "stars [Go] 10 125 35 15 [main]

staticcreate "panel "text1 [Star sides] 15 10 70 10
scrollbarcreate "panel "sides 15 20 70 10 [tellbar1]
scrollbarset "sides 3 30 15

staticcreate "panel "text2 [Side Size] 15 40 70 10
scrollbarcreate "panel "size 15 50 70 10 [tellbar2]
scrollbarset "size 20 100 60

staticcreate "panel "text3 [Head Angle] 15 70 70 10
scrollbarcreate "panel "head_angle 15 80 70 10 [tellbar3]
scrollbarset "head_angle 10 90 40

staticcreate "panel "text4 [Recursion level] 15 100 70 10
scrollbarcreate "panel "level 15 110 70 10 [tellbar4]
scrollbarset "level 1 8 4

end

to star.main

; These are some additions to Yehuda"s marvelous
; Recursive Star program. 
; Just adds some control scrollbars and buttons
; to maintain input parameters.

windowcreate "main "panel [Control panel] 0 0 100 
160[star.control.setup]
end

to tellbar1
staticupdate "text1 (sentence "Star "sides scrollbarget "sides)
end

to tellbar2
staticupdate "text2 (sentence "Max.  "size scrollbarget "size)
end

to tellbar3
staticupdate "text3 (sentence "Head  "angle scrollbarget "head_angle)
end

to tellbar4
staticupdate "text4 (sentence "Recursion "level scrollbarget "level)
end

to turn
op(360/:sides+:head_ang)/2
end

 

______________________________________________________
Get Your Private, Free Email at http://www.hotmail.com
---------------------------------------------------------------
Please post messages to the Logo forum to logo-l@gsn.org.  Mail
questions about the list administration to logofdn@gsn.org.  To
unsubscribe send    unsubscribe logo-l    to majordomo@gsn.org.